RXS_Crypt()

**FREE
// This example code performs AES128 encryption on an ISO88591 string
Ctl-Opt ActGrp(*New) BndDir('RXSBND');

/COPY QRPGLECPY,RXSCB

Dcl-Ds AESDS LikeDS(RXS_AESCryptDS_t);
Dcl-S Input Like(RXS_Var1Kv_t);
Dcl-S Output Like(RXS_Var1Kv_t);

Input = 'abc';

RXS_ResetDS( AESDS : RXS_DS_TYPE_AESCRYPT );

AESDS.PadInput = RXS_YES;
AESDS.Algorithm = RXS_CRYPT_AES128_ALGORITHM;
AESDS.BlockMode = RXS_CRYPT_AESBLOCKMODE_CBC;
AESDS.EncryptDecrypt = RXS_ENCRYPT;

// We're providing the input string in our job CCSID but we want
//  RXS_Crypt to convert it to the ISO88591 equivalent and then
//  encrypt. If you plan to exchange data with non-IBM i systems
//  this is usually the route you'll want to go, though you may
//  instead need to encrypt as UTF-8 by using RXS_CCSID_UTF8.
AESDS.InputCCSID = RXS_CCSID_JOB;
AESDS.EncryptAsCcsid = RXS_CCSID_ISO88591;

AESDS.Key128 = x'00000000000000000000000000000000';
AESDS.KeyFormat = RXS_CRYPT_AESKEYFORMAT_BIN;
AESDS.OutputPadOption = RXS_CRYPT_PADOUTPUT_NONE;
AESDS.InitializationVector = x'00000000000000000000000000000000';

// After encryption, the Output field will contain a binary string with the hex
//  value: d29999ea2b049ae79cb86ba27b1a5f55
Output = RXS_Crypt( Input : AESDS );

//  RXS_JobLog will attempt to treat this as a string which will lead to
//   the output looking like garbage characters.
RXS_JobLog( 'Encrypted output: %s' : Output );

// The easiest way to view and verify the encryption worked correctly is
//  to look at the value of the Output field in debug in hex mode.
//  Using STRDBG, you would view Output in hex mode by typing in this:
//
//    eval Output:x 50
return;

**FREE
// This example code performs AES128 decryption on an ISO88591 string
Ctl-Opt ActGrp(*New) BndDir('RXSBND');

/COPY QRPGLECPY,RXSCB

Dcl-Ds AESDS LikeDS(RXS_AESCryptDS_t);
Dcl-S Input Like(RXS_Var1Kv_t);
Dcl-S Output Like(RXS_Var1Kv_t);

// We have a sequence of hex bytes and not a string to decrypt
Input = x'd29999ea2b049ae79cb86ba27b1a5f55';

RXS_ResetDS( AESDS : RXS_DS_TYPE_AESCRYPT );

// Any non-IBM i system you work with isn't going to deal with data in EBCDIC so
//  RXS_Crypt is set up to facilitate handling conversion to/from non-EBCDIC
//  character sets. In this case the string is in ISO8859-1, so we indicate
//  that here:
AESDS.InputCcsid = RXS_CCSID_ISO88591;
AESDS.EncryptAsCcsid = RXS_CCSID_ISO88591;

// Indicate that we're performing decryption and not encryption
AESDS.EncryptDecrypt = RXS_DECRYPT;

AESDS.PadInput = RXS_YES;
AESDS.Algorithm = RXS_CRYPT_AES128_ALGORITHM;
AESDS.BlockMode = RXS_CRYPT_AESBLOCKMODE_CBC;

AESDS.Key128 = x'00000000000000000000000000000000';
AESDS.KeyFormat = RXS_CRYPT_AESKEYFORMAT_BIN;

// Make sure you set the key CCSID appropriately
AESDS.KeyCCSID = RXS_CCSID_JOB;

// For output generally RXS_CRYPT_PADOUTPUT_CHAR is what you should use.
//  This will make RXS_Crypt pad the output with null bytes, which is typically
//  what you want.
AESDS.OutputPadOption = RXS_CRYPT_PADOUTPUT_CHAR;

AESDS.InitializationVector = x'00000000000000000000000000000000';

// After encryption, the Output field will contain a binary string with the hex
//  value: 616263
// This corresponds to the ISO88591 characters 'abc' as expected.
Output = RXS_Crypt( Input : AESDS );

//  RXS_JobLog will attempt to treat this as a string which will lead to
//   the output looking like garbage characters.
RXS_JobLog( 'Decrypted output: %s' : Output );

// The easiest way to view and verify the encryption worked correctly is
//  to look at the value of the Output field in debug in hex mode.
//  Using STRDBG, you would view Output in hex mode by typing in this:
//
//    eval Output:x 50
return;

**FREE
// This example code performs AES128 encryption on an EBCDIC string
Ctl-Opt ActGrp(*New) BndDir('RXSBND');

/COPY QRPGLECPY,RXSCB

Dcl-Ds AESDS LikeDS(RXS_AESCryptDS_t);
Dcl-S Input Like(RXS_Var1Kv_t);
Dcl-S Output Like(RXS_Var1Kv_t);

Input = 'abc';

RXS_ResetDS( AESDS : RXS_DS_TYPE_AESCRYPT );

AESDS.PadInput = RXS_YES;
AESDS.Algorithm = RXS_CRYPT_AES128_ALGORITHM;
AESDS.BlockMode = RXS_CRYPT_AESBLOCKMODE_CBC;
AESDS.EncryptDecrypt = RXS_ENCRYPT;

// We're providing the input as our job CCSID, and we want it encrypted
//  using EBCDIC CCSID 37. This is rarely something you want to do when you
//  will be exchanging encrypted data with other non-IBM i systems as most
//  other systems will expect to be working with ISO88591 or UTF-8 data.
AESDS.InputCCSID = RXS_CCSID_JOB;
AESDS.EncryptAsCCSID = RXS_CCSID_EBCDIC;

AESDS.Key128 = x'00000000000000000000000000000000';
AESDS.KeyFormat = RXS_CRYPT_AESKEYFORMAT_BIN;
AESDS.OutputPadOption = RXS_CRYPT_PADOUTPUT_NONE;
AESDS.InitializationVector = x'00000000000000000000000000000000';

// After encryption, the Output field will contain a binary string with the hex
//  value: 81743865f4a9ce13349d67f5642fd971
Output = RXS_Crypt( Input : AESDS );

//  RXS_JobLog will attempt to treat this as a string which will lead to
//   the output looking like garbage characters.
RXS_JobLog( 'Encrypted output: %s' : Output );

// The easiest way to view and verify the encryption worked correctly is
//  to look at the value of the Output field in debug in hex mode.
//  Using STRDBG, you would view Output in hex mode by typing in this:
//
//    eval Output:x 50
return;